/*
Copyright 2024 The Kubernetes Authors.

Licensed under the Apache License, Version 2.0 (the "License");
you may not use this file except in compliance with the License.
You may obtain a copy of the License at

    http://www.apache.org/licenses/LICENSE-2.0

Unless required by applicable law or agreed to in writing, software
distributed under the License is distributed on an "AS IS" BASIS,
WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
See the License for the specific language governing permissions and
limitations under the License.
*/

resource "google_compute_global_address" "prow" {
  for_each   = toset(["IPV4", "IPV6"])
  project    = module.project.project_id
  name       = "prow-ingress-${lower(substr(each.key, 2, 2))}"
  ip_version = each.key
}

resource "google_compute_address" "prow_nat" {
  count   = 4
  name    = "prow-nat-${count.index}"
  project = module.project.project_id
  region  = "us-central1"
}

resource "google_compute_address" "utility_ingress" {
  for_each           = toset(["IPV4", "IPV6"])
  name               = "utility-ingress-${lower(substr(each.key, 2, 2))}"
  project            = module.project.project_id
  region             = "us-central1"
  ip_version         = each.key
  subnetwork         = each.key == "IPV6" ? module.vpc.subnets["us-central1/subnet-01"].id : null
  ipv6_endpoint_type = each.key == "IPV6" ? "NETLB" : null
}