
#global defaults
isEmpty(QMAKE_REZ) {
    QMAKE_REZ = /Developer/Tools/Rez
}
isEmpty(REZ_DIR):REZ_DIR = .
isEmpty(QMAKE_EXT_REZ):QMAKE_EXT_REZ = .rsrc

rez_source.CONFIG += no_link
rez_source.dependency_type = TYPE_C
rez_source.commands = $$QMAKE_REZ ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT} -useDF
rez_source.output = $$REZ_DIR/${QMAKE_FILE_BASE}$${first(QMAKE_EXT_REZ)}
rez_source.input = REZ_FILES
rez_source.name = REZ ${QMAKE_FILE_IN}
silent:rez_source.commands = @echo rez ${QMAKE_FILE_IN} && $$rez_source.commands
QMAKE_EXTRA_COMPILERS += rez_source
